H DFTACTGRP(*NO) BNDDIR('ERPGSDK')                                                             
      **********************************************************************                        
     FCATUSER1  IF   E           K DISK    USROPN                                                   
      **********************************************************************                        
      * Prototypes                                                                                  
      **********************************************************************                        
      /COPY QCOPYSRC,P.ERPGSDK                                                                      
      **********************************************************************                        
     D DftPath         S             64    INZ('/www/erpgsdk/catalog+                               
     D                                          /templates/')                                       
      *                                                                                             
      * Data read in from Web Page                                                                  
     D user            S             30                                                             
      *                                                                                             
      * Work Variables                                                                              
      **********************************************************************                        
     C                   callp     #startup                                                         
      *                                                                                             
     C                   Exsr      $Input                                                           
      *                                                                                             
     C                   callp     #setPath(DftPath)                                                
     C                   callp     #loadTemplate('userheader.erpg')                                 
     C                   callp     #writeThisSec('first')                                           
      *                                                                                             
     C                   OPEN      CATUSER1                             99                          
      *                                                                                             
     C                   if        (not *IN99)                                                      
     C                   EXSR      $Display                                                         
     C                   CLOSE     CATUSER1                                                         
     C                   else                                                                       
     C                   callp     #writeThisSec('fileerror')                                       
     C                   endif                                                                      
      *                                                                                             
     C                   callp     #cleanup                                                         
      *                                                                                             
     C                   Eval      *InLR = *On                                                      
      ****************************************************************                              
      * Display User Header Information                              *                              
      ****************************************************************                              
     C     $Display      BEGSR                                                                      
      *                                                                                             
     C     user          CHAIN     CATUSER1                                                         
      *                                                                                             
     C                   if        (%found(CATUSER1))                                               
     C                   callp     #loadSection('user')                                             
     C                   callp     #replaceData('/%username%/':CUNAME)                              
     C                   callp     #writeSection                                                    
     C                   else                                                                       
     C                   callp     #writeThisSec('nouser')                                          
     C                   endif                                                                      
      *                                                                                             
     C                   ENDSR                                                                      
      **********************************************************************                        
      * Read Input                                                                                  
      **********************************************************************                        
     C     $Input        BEGSR                                                                      
      *                                                                                             
     C                   eval      user = #getCookie('user')                                        
      *                                                                                             
     C                   ENDSR