H DFTACTGRP(*NO) BNDDIR('ERPGSDK')                                                             
      ****************************************************************                              
     FPOHEADPF  IF   E           K DISK    USROPN                                                   
     FPODETPF   IF   E           K DISK    USROPN                                                   
      ****************************************************************                              
      * Prototypes                                                   *                              
      ****************************************************************                              
      /COPY QCOPYSRC,P.ERPGSDK                                                                      
      /COPY QCOPYSRC,P.LIBL                                                                         
      ****************************************************************                              
     D PoDate          S             10                                                             
     D IsPO            S               N                                                            
     D IsDetail        S               N                                                            
      ****************************************************************                              
     C                   callp     #startup                                                         
      *                                                                                             
     C                   callp     #pushLib('BVSTONECGI')                                           
     C                   callp     #writeTemplate('stdhtmlheader.erpg')                             
      *                                                                                             
     C                   callp     #loadTemplate('data1.erpg')                                      
     C                   callp     #writeThisSec('top')                                             
      *                                                                                             
     C                   OPEN      POHEADPF                             99                          
     C                   OPEN      PODETPF                              98                          
      *                                                                                             
     C                   if        (*IN98 or *IN99)                                                 
     C                   callp     #writeThisSec('fileerror')                                       
     C                   else                                                                       
     C                   EXSR      $Display                                                         
     C                   endif                                                                      
      *                                                                                             
     C                   if        (not *IN99)                                                      
     C                   CLOSE     POHEADPF                                                         
     C                   endif                                                                      
      *                                                                                             
     C                   if        (not *IN98)                                                      
     C                   CLOSE     PODETPF                                                          
     C                   endif                                                                      
      *                                                                                             
     C                   callp     #writeThisSec('end')                                             
     C                   callp     #popLib('BVSTONECGI')                                            
      *                                                                                             
     C                   callp     #cleanup                                                         
     C                   eval      *INLR = *on                                                      
      ****************************************************************                              
      *  Display the PO                                                                             
      ****************************************************************                              
     C     $Display      BEGSR                                                                      
      *                                                                                             
     C                   eval      IsPO = *OFF                                                      
     C                   READ      POHEADPF                                                         
      *                                                                                             
     C                   dow       (not %eof(POHEADPF))                                             
     C                   callp     #loadSection('pohead')                                           
     C                   eval      IsPO = *ON                                                       
     C                   callp     #replaceData('/%po%/':PHPONO)                                    
     C     *USA          MOVE      PHPODATE      PoDate                                             
     C                   callp     #replaceData('/%podate%/':PoDate)                                
     C                   callp     #replaceData('/%vendor%/':                                       
     C                                           %editc(PHVENNO:'Z') +                              
     C                                           ' - ' +                                            
     C                                           %trim(PHVENDSC))                                   
     C                   callp     #replaceData('/%misc%/':                                         
     C                                           %editc(PHMISCCHG:'L'))                             
     C                   callp     #writeSection                                                    
     C                   EXSR      $Detail                                                          
     C                   READ      POHEADPF                                                         
     C                   enddo                                                                      
      *                                                                                             
     C                   if        (not IsPO)                                                       
     C                   callp     #writeThisSec('nopo')                                            
     C                   endif                                                                      
      *                                                                                             
     C                   ENDSR                                                                      
      ****************************************************************                              
      *  Display the PO Details                                                                     
      ****************************************************************                              
     C     $Detail       BEGSR                                                                      
      *                                                                                             
     C                   eval      IsDetail = *OFF                                                  
      *                                                                                             
     C     PHPONO        SETLL     PODETPF                                                          
     C     PHPONO        READE     PODETPF                                                          
      *                                                                                             
     C                   dow       (not %eof(PODETPF))                                              
      *                                                                                             
     C                   if        (not IsDetail)                                                   
     C                   callp     #writeThisSec('podet1')                                          
     C                   eval      IsDetail = *ON                                                   
     C                   endif                                                                      
      *                                                                                             
     C                   callp     #loadSection('podet2')                                           
     C                   callp     #replaceData('/%line%/':                                         
     C                                          %editc(PDLINE:'Z'))                                 
     C                   callp     #replaceData('/%qty%/':                                          
     C                                          %editc(PDQTY:'Z'))                                  
     C                   callp     #replaceData('/%item%/':PDITMNO)                                 
     C                   callp     #replaceData('/%desc%/':PDITMDSC)                                
     C                   callp     #replaceData('/%price%/':                                        
     C                                          %editc(PDUNTPRC:'L'))                               
     C                   callp     #writeSection                                                    
     C     PHPONO        READE     PODETPF                                                          
     C                   enddo                                                                      
      *                                                                                             
     C                   if        (not IsDetail)                                                   
     C                   callp     #writeThisSec('podet3')                                          
     C                   else                                                                       
     C                   callp     #writeThisSec('podet4')                                          
     C                   endif                                                                      
      *                                                                                             
     C                   ENDSR