H DFTACTGRP(*NO) BNDDIR('ERPGSDK')                                                             
      ****************************************************************                              
     FPODETPF   IF   E           K DISK    USROPN                                                   
      ****************************************************************                              
      * Prototypes                                                   *                              
      ****************************************************************                              
      /COPY QCOPYSRC,P.ERPGSDK                                                                      
      /COPY QCOPYSRC,P.STRING                                                                       
      ****************************************************************                              
     D InCount         S             10i 0                                                          
      *                                                                                             
     D Count           S             10i 0                                                          
     D IsDetail        S               N                                                            
      ****************************************************************                              
     C                   callp     #startup                                                         
     C                   eval      InCount = #CtoN(#getData('count'))                               
     C                   callp     #writeTemplate('stdhtmlheader.erpg')                             
     C                   callp     #loadTemplate('ajax2.erpg')                                      
      *                                                                                             
     C                   OPEN      PODETPF                              98                          
      *                                                                                             
     C                   if        (*IN98)                                                          
     C                   callp     #writeThisSec('fileerror')                                       
     C                   else                                                                       
     C                   EXSR      $Detail                                                          
     C                   endif                                                                      
      *                                                                                             
     C                   if        (not *IN98)                                                      
     C                   CLOSE     PODETPF                                                          
     C                   endif                                                                      
      *                                                                                             
     C                   CALLP     #cleanup                                                         
      *                                                                                             
     C                   eval      *INLR = *on                                                      
      ****************************************************************                              
      *  Display the PO Details                                                                     
      ****************************************************************                              
     C     $Detail       BEGSR                                                                      
      *                                                                                             
     C                   eval      IsDetail = *OFF                                                  
      *                                                                                             
     C     *LOVAL        SETLL     PODETPF                                                          
     C                   READ      PODETPF                                                          
      *                                                                                             
     C                   dow       (not %eof(PODETPF)) and (Count < InCount)                        
      *                                                                                             
     C                   if        (not IsDetail)                                                   
     C                   callp     #writeThisSec('podet1')                                          
     C                   eval      IsDetail = *ON                                                   
     C                   endif                                                                      
      *                                                                                             
     C                   callp     #loadSection('podet2')                                           
     C                   callp     #replaceData('/%line%/':                                         
     C                                          %editc(PDLINE:'Z'))                                 
     C                   callp     #replaceData('/%qty%/':                                          
     C                                          %editc(PDQTY:'Z'))                                  
     C                   callp     #replaceData('/%item%/':PDITMNO)                                 
     C                   callp     #replaceData('/%desc%/':PDITMDSC)                                
     C                   callp     #replaceData('/%price%/':                                        
     C                                          %editc(PDUNTPRC:'L'))                               
     C                   callp     #writeSection                                                    
     C                   eval      Count = (Count + 1)                                              
     C                   READ      PODETPF                                                          
     C                   enddo                                                                      
      *                                                                                             
     C                   if        (not IsDetail)                                                   
     C                   callp     #writeThisSec('podet3')                                          
     C                   else                                                                       
     C                   callp     #writeThisSec('podet4')                                          
     C                   endif                                                                      
      *                                                                                             
     C                   ENDSR